Distance warning ( Cảnh báo khoảng cách với Arduino)
Trong dự án này, chúng tôi sử dụng một cảm biến siêu âm và ba nhóm đèn LED (xanh, vàng, đỏ) để mô phỏng hệ thống cảnh báo khoảng cách kiểu radar với bo mạch Arduino.
Hệ thống đo khoảng cách đến một vật thể và kích hoạt các nhóm đèn LED khác nhau dựa trên mức độ gần của vật thể: đèn LED xanh cho biết khoảng cách an toàn (≤15 cm), đèn LED vàng cảnh báo rằng vật thể đang tiến gần hơn (≤10 cm), và đèn LED đỏ tín hiệu cảnh báo khoảng cách nguy cấp (≤5 cm). Các đèn LED sẽ bật từ trái sang phải và tắt từ phải sang trái để tăng cường hiệu ứng trực quan.
Linh kiện cần có cho dự án như sau:
|
SN |
Linh Kiện |
SL |
LINK |
|---|---|---|---|
|
1 |
Arduino UNO R4 WIFI |
1 |
|
|
2 |
USB Type-C cable |
1 |
|
|
3 |
Breadboard |
1 |
|
|
4 |
Wires |
Several |
|
|
5 |
1kΩ resistor |
several |
|
|
6 |
Ultrasonic Sensor Module |
1 |
|
|
7 |
LED |
several |
|
Kết nối chung:
Đèn LED
- Kết nối cực âm (cathode) của đèn LED vào bus nguồn âm trên breadboard.
- Kết nối cực dương (anode) của đèn LED qua một điện trở 1kΩ đến các chân 4 đến 12 trên Arduino.
Module cảm biến siêu âm
- Trig: Kết nối đến chân 3 trên Arduino.
- Echo: Kết nối đến chân 2 trên Arduino.
- GND: Kết nối vào bus nguồn âm của breadboard.
- VCC: Kết nối vào bus nguồn đỏ của breadboard.
CODE:
const int echoPin = 2; // Echo pin of the ultrasonic sensor
const int trigPin = 3; // Trig pin of the ultrasonic sensor
// Three LED groups from left to right
const int greenLEDs[] = {12, 11, 10}; // Green LEDs = safe distance
const int yellowLEDs[] = {9, 8, 7}; // Yellow LEDs = getting closer
const int redLEDs[] = {6, 5, 4}; // Red LEDs = very close
// Flags to track if each LED group is on
bool greenOn = false;
bool yellowOn = false;
bool redOn = false;
void setup() {
Serial.begin(9600); // Start the serial monitor
pinMode(echoPin, INPUT); // Set echo pin as input
pinMode(trigPin, OUTPUT); // Set trig pin as output
// Set all LED pins as output
for (int i = 0; i < 3; i++) {
pinMode(greenLEDs[i], OUTPUT);
pinMode(yellowLEDs[i], OUTPUT);
pinMode(redLEDs[i], OUTPUT);
}
Serial.println("Ultrasonic sensor:");
}
void loop() {
float distance = readSensorData(); // Read distance in cm
Serial.print(distance);
Serial.println(" cm");
if (distance <= 15) {
// 15 cm or less: turn on green LEDs
if (!greenOn) {
turnOnLEDs(greenLEDs);
greenOn = true;
}
if (distance <= 10) {
// 10 cm or less: turn on yellow LEDs
if (!yellowOn) {
turnOnLEDs(yellowLEDs);
yellowOn = true;
}
if (distance <= 5) {
// 5 cm or less: turn on red LEDs
if (!redOn) {
turnOnLEDs(redLEDs);
redOn = true;
}
} else {
// More than 5 cm: turn off red LEDs
if (redOn) {
turnOffLEDsReverse(redLEDs);
redOn = false;
}
}
} else {
// More than 10 cm: turn off yellow LEDs
if (yellowOn) {
turnOffLEDsReverse(yellowLEDs);
yellowOn = false;
}
}
} else {
// More than 15 cm: turn off all LEDs
if (redOn) {
turnOffLEDsReverse(redLEDs);
redOn = false;
}
if (yellowOn) {
turnOffLEDsReverse(yellowLEDs);
yellowOn = false;
}
if (greenOn) {
turnOffLEDsReverse(greenLEDs);
greenOn = false;
}
}
delay(50); // Short delay to avoid reading too frequently
}
// Measure distance using ultrasonic sensor
float readSensorData() {
digitalWrite(trigPin, LOW);
delayMicroseconds(2);
digitalWrite(trigPin, HIGH);
delayMicroseconds(10);
digitalWrite(trigPin, LOW);
float duration = pulseIn(echoPin, HIGH);
return duration / 58.0; // Convert time to distance in cm
}
// Turn on LEDs from left to right
void turnOnLEDs(const int ledArray[]) {
for (int i = 0; i < 3; i++) {
if (digitalRead(ledArray[i]) == LOW) {
digitalWrite(ledArray[i], HIGH);
delay(60); // Add delay for visual effect
}
}
}
// Turn off LEDs from right to left
void turnOffLEDsReverse(const int ledArray[]) {
for (int i = 2; i >= 0; i--) {
if (digitalRead(ledArray[i]) == HIGH) {
digitalWrite(ledArray[i], LOW);
delay(60); // Add delay for visual effect
}
}
}
